nsmcp::CodexQuestionBackend object method initializationSummary (public)

 nsmcp::CodexQuestionBackend[i] initializationSummary diagnostic

Defined in /usr/local/ns/tcl/nsmcp/question-backend.tcl

Explain a retained initialization snapshot for the administrator UI.

Parameters:
diagnostic (required)
Sanitized backend diagnostics.
Returns:
A bounded description of observed blocked reads.

Testcases:
No testcase defined.
Source code:
if {![dict exists $diagnostic initializationCapture]} {return ""}
set capture [dict merge {processes {} status unavailable reason unknown} [dict get $diagnostic initializationCapture]]
set findings {}
foreach process [dict get $capture processes] {
    set process [dict merge {threads {}} $process]
    foreach thread [dict get $process threads] {
        set thread [dict merge {state {} name unknown waitChannel unknown} $thread]
        if {[dict get $thread state] ne "D"} {continue}
        set finding "PID [dict get $process pid], thread [dict get $thread tid]"
        append finding " ([dict get $thread name]) was blocked in [dict get $thread waitChannel]"
        if {[dict exists $thread readOperation]} {
            append finding " during [dict get $thread readOperation]"
        }
        if {[dict exists $thread fileDescriptor]} {
            append finding ", fd [dict get $thread fileDescriptor]"
        }
        if {[dict exists $thread filePath]} {
            append finding ", file [dict get $thread filePath]"
        } elseif {[dict exists $thread readOperation]} {
            append finding ", file path unavailable"
        }
        lappend findings $finding
        if {[llength $findings]>=3} {break}
    }
    if {[llength $findings]>=3} {break}
}
if {$findings ne {}} {
    return "Initialization snapshot: [join $findings {; }]. This is the state observed at timeout."
}
return "Initialization snapshot: [dict get $capture status] ([dict get $capture reason]); no blocked thread was observed. Details are in the server log."
XQL Not present:
Generic, PostgreSQL, Oracle
[ hide source ] | [ make this the default ]
Show another procedure: