github::ActivityMonitor method record_rate_limit (protected)

 <instance of github::ActivityMonitor[i]> record_rate_limit status \
    headers body

Defined in packages/xowiki/tcl/github-activity-monitor-procs.tcl

Parameters:
status (required)
headers (required)
body (required)

Testcases:
No testcase defined.
Source code:
set now [clock seconds]
set remaining ""
set reset ""
set retry ""
foreach {name variable} {
    x-ratelimit-remaining remaining x-ratelimit-reset reset retry-after retry
} {
    if {[dict exists $headers $name]} {
        set $variable [string trim [dict get $headers $name]]
    }
}
set exhausted [expr {$remaining eq "0"}]
set limited [expr {$exhausted || $status == 429
    || ($status == 403 && ($retry ne ""
        || [regexp -nocase {rate limit|secondary limit|abuse detection} $body]))}]
if {!$limited} {
    if {$status >= 200 && $status < 300
        && [:get_state github_rate_backoff 0] ne "0"} {
        :set_state github_rate_backoff 0
    }
    return
}

set until 0
if {$exhausted && [string is wideinteger -strict $reset] && $reset > $now} {
    set until [expr {$reset + 2}]
}
if {[string is integer -strict $retry] && $retry >= 0} {
    set until [expr {max($until, $now + $retry + 2)}]
} elseif {$retry ne "" && ![catch {clock scan $retry -gmt 1} retry_epoch]} {
    set until [expr {max($until, $retry_epoch + 2)}]
}
# Missing/invalid headers, or repeated secondary limits: at least
# one minute, doubling on repeated failures up to one hour.
if {$until <= $now} {
    set previous [:get_state github_rate_backoff 0]
    if {![string is integer -strict $previous] || $previous < 0} {set previous 0}
    set delay [expr {min(3600, max(60, 2 * $previous))}]
    set until [expr {$now + $delay}]
    :set_state github_rate_backoff $delay
}
set previous [:get_state github_not_before 0]
if {[string is wideinteger -strict $previous]} {set until [expr {max($until, $previous)}]}
:set_state github_not_before $until
ns_log Warning "GitHub: requests paused until [clock format $until -gmt 1 -format {%Y-%m-%d %H:%M:%S UTC}]"
XQL Not present:
Generic, PostgreSQL, Oracle
[ hide source ] | [ make this the default ]
Show another procedure: